Sunday, June 25, 2017

Cara Membuat Form Help Interaktif Aplikasi VBA Excel

Cara Membuat Form Help Interaktif Aplikasi VBA Excel - Fungsi Menu Hepl Apliksi untuk memberikan penjelasan secara detail cara menggunakan aplikasi kepada pengguna aplikasi. Aplikasi yang bagus merupakan aplikasi yang mencantumkan penjelasan cara menggunakan aplikasi secara profesional. Semua Aplikasi yang dibuat secara profesional selalu menyematkan menu Help. Pengguna Aplikasi tidak akan kalang-kabut untuk mempelajari cara kerja aplikasi.

Coba saja dibayangkan sebuah aplikasi yang sangat dibutuhkan oleh pengguna namun tidak mencantumkan menu help atau penjelasan cara pemakaian dan gunaan aplikasi tersebut. Sudah pasti pengguna akan mempelajarinya secara manual dengan mencoba-coba tiap tombol menu yang ada dalam aplikasi. Tidak sedikit pula beberapa aplikasi mencantumkan tombol menu help di aplikasi namun ketika pengguna mengklik pada tombol help tersebut akan mengarahkan pengguna ke link web yang menjelaskan penggunaan aplikasi. cara ini memang lebih mantap namun dibutuhkan jaringan internet untuk mengakses laman help tersebut.


Penjelasan yang penjang lebar berkenaan tiap fungsi dari filtur aplikasi sangat membutuhkan form yang luas dan lebar, tentu saja kita harus mengakalinya agar form tersebut tidak banyak dan tidak pula terlalu lebar hingga pengguna jadi kepayahan dalam melihat form help tersebut. Pada posting ini kita akan sama-sama mencoba membuat Form Help Aplikasi yang lebih Interaktif dan lebih efesien dalam penggunaan lebar Form Help. Ikuti saja penjelasan ala OTODIDAK dalam posting ini.

Langkah - langkah Membuat Form Help Interaktif Aplikasi VBA Excel
  • Langkah pertama sudah pasti anda harus membuka lembar kerja Micoroft excel, Pada Sheet1 ubahlah nama sheet1 menjadi "HelpSheet". 
  • Buatlah data detail help yang ingin ditampilkan pada userform pada worksheet "HelpSheet", Pada tiap kolom A tuliskan isi utama dari menu, dan tiap kolom B tulislah penjelasan tiap menu sesuai dengan yang tercantum pada tiap kolom A dan simpan file dalam format Macro atau Binary perhatikan gambar dibawah ini. 
  • Selanjutnya merancang UserForm, pilih Tap Developer klik menu Visual Basic, pada jendela Visual Basic kita akan merancang form seperti yang terlihat pada gambar gif diatas. Inser UserForm dan lengkapi element-element yang dibutuhkan melalui fasilitas yang sudah tersedia pada ToolBox yaitu Combobox1, Frame1, Label1, CommandButton1, CommandButton2 dan CommandButton3. Letakkan tiap element tersebut persis seperti gambar dibawah ini.
  • Mengatur properties setiap element dengan ketentuan sebagai berikut ini,  Yang perlu diperhatikan dari properties adalah (Name), harus sesuai dengan yang tertulis karena (Name) tersebut akan ada dalam kode Vba, Jika (Name) tidak sesuai maka akan terjadi error saat kode Vba dijalankan. Properties selain (Name) dapat disesuaikan dengan selera masing-masing.
Properties UserForm1 
(Name) = FormHelp
Caption = Help
BackColor = &H008AA882&

Properties Combobox1
(Name) = ComboBoxTopics
BackColor = &H00000040&
BorderColor = &H000000FF&
BorderStyle = 1 - FmBorderStyleSingle
ForeColor = &H00FFFFFF&

Properties Frame1
(Name) = Frame1
Captionnya dihapus saja
BackColor = &H00000040&
BorderColor = &H000000FF&
BorderStyle = 1 - FmBorderStyleSingle
KeepScrollBarsVisible = 2 - FmScrollBarsVertical
ScrollBarsVisible = 2 - FmScrollBarsVertical
SpecialEffect = 0 - FmSpecialEffectFlat

Properties Label1
(Name) = LabelTopic
Captionnya dihapus saja
BackColor = &H00000040&
BorderColor = &H000000FF&

Properties CommandButton
CommandButton1 (Name) = ExitButton, Caption = Exit
CommandButton2 (Name) = PreviousButton, Caption = < Previous
CommandButton3 (Name) = NextButton, Caption = Next >
  • Langkah selanjutnya kita akan menulis kode pada form kode. Double Klik pada userform. Pada Jendela Code pilih objek (General) Event (Declaration) dan tulislah kode dibawah ini
Option Explicit
Dim TopicCount As Integer
Dim CurrentTopic As Integer
Dim HelpSheet As Worksheet

Const HelpSheetName As String = "HelpSheet"

Const HelpFormCaption As String = "Help"
  • Tulislah kode dibawah ini pada objek (General) dengan Event UpdateForm yang akan muncul otomatis
Private Sub UpdateForm()
    ComboBoxTopics.ListIndex = CurrentTopic - 1
    Me.Caption = HelpFormCaption & " (" & CurrentTopic & " of " & TopicCount & ")"
    With LabelTopic
        .Caption = HelpSheet.Cells(CurrentTopic, 2)
        .AutoSize = False
        .Width = 212
        .AutoSize = True
    End With
    Frame1.ScrollTop = 1
    Frame1.ScrollHeight = LabelTopic.Height + 5
    If CurrentTopic = 1 Then PreviousButton.Enabled = False Else PreviousButton.Enabled = True
    If CurrentTopic = TopicCount Then NextButton.Enabled = False Else NextButton.Enabled = True
    On Error Resume Next
    If NextButton.Enabled Then NextButton.SetFocus Else PreviousButton.SetFocus
End Sub
  • Tulislah kode dibawah ini pada objek (General) dengan Event SheetExists yang akan muncul otomatis
Private Function SheetExists(sht) As Boolean
    Dim TempSheet As Worksheet
    On Error Resume Next
    Set TempSheet = ThisWorkbook.Worksheets(sht)
    If Err = 0 Then SheetExists = True Else SheetExists = False
End Function
  • Tulislah kode dibawah ini pada objek UserForm dengan Event Initialize
Private Sub UserForm_Initialize()
    Dim Row As Integer
    Set HelpSheet = ThisWorkbook.Sheets(HelpSheetName)
    TopicCount = Application.WorksheetFunction.CountA(HelpSheet.Range("A:A"))
    For Row = 1 To TopicCount
        ComboBoxTopics.AddItem HelpSheet.Cells(Row, 1)
    Next Row
    ComboBoxTopics.ListIndex = 0
    CurrentTopic = 1
    UpdateForm
End Sub
  • Selanjutnya kita akan menuliskan perintah untuk Combobox. Klik kanan Combobox pilih View Code dan tulislah kode berikut ini.
Private Sub ComboBoxTopics_Click()
'   Executed when the ComboBox is changed
    CurrentTopic = ComboBoxTopics.ListIndex + 1
    UpdateForm
End Sub
  • Menuliskan kode untuk tombol Next yang akan melakukan pecarian data berikutnya, Klik kanan CommandButton3 dengan Caption Next > dan tulislah kode berikut ini.
Private Sub NextButton_Click()
'   Executed when the NextButton is clicked
    If CurrentTopic <> TopicCount Then
        CurrentTopic = CurrentTopic + 1
        UpdateForm
    End If
End Sub
  • Menuliskan kode untuk tombol Previos yang akan melakukan pecarian data sebelumnya, Klik kanan CommandButton2 dengan Caption <Previous dan tulislah kode berikut ini.
Private Sub PreviousButton_Click()
'   Executed when the PreviousButton is clicked
    If CurrentTopic <> 1 Then
        CurrentTopic = CurrentTopic - 1
        UpdateForm
    End If
End Sub
  • Menuliskan kode untuk tombol Exit yang akan menghentikan tampilan UserForm, Klik kanan CommandButton1 dengan Caption Exit dan tulislah kode berikut ini.
Private Sub ExitButton_Click()
    Unload Me
End Sub

Selesai..!! Bila anda telah menempatkan kode yang benar dan tepat maka aplikasi yang anda bikin untuk Form Help akan tampil sebagaimana yang terlihat pada gambar gif posting ini. Demikian posting Cara Membuat Form Help Interaktif Aplikasi VBA Excel semoga dapat dijadikan referensi dalam membangun Aplikasi berbasis VBA Excel yang dilengkapi dengan Form Help yang lebih interaktif.


Nama Admin Zaki Fitriadi, Pengangguran, Blogger Awam Kelahiran Banda Aceh 1982, Mengenal Blog Tahun 2010, Baru Aktif Tahun 2015, Berbagi Apa Yang Dipejari Secara Otodidak di Dunia Maya

Komentar Anda Sangat Menentukan Kelangsungan Blog ini
EmoticonEmoticon